// *********************************
// Etude de la chute d'un corps
// Programme de mécanique de seconde
// Dominique LEFEBVRE
// 26 février 2007
// *********************************

clear;             // Initialisation de toutes les variables

// Initialisation des paramètres de simulation
deltaT = 0.01;      // base de temps = 0,01 seconde

// Initialsation des paramètres du mouvement
g  =  9.81;        // accélération de la pesanteur 9,81 N.m-2 (ou N.kg)
v0 =  10 ;          // vitesse initiale du corps (en m.s-1)
y0 =  10;          // ordonnée initiale du corps (en m)

// Initialisation des variables de calcul
x(1) = 0;          // abscisse initiale du corps = 0;
y(1) = y0;         // ordonnée initiale = y0, paramètre de la simulation
vX = v0;           // vitesse horizontale initiale du corps - cette vitesse est constante
vY(1) = 0;         // vitesse verticale initiale du corps

// Initialisation graphique
xbasc();

// Calcul du mouvement
i = 2;                            // indice de boucle 
while (y(i-1) > 0)                // la boucle est exécutée tant que le corps n'est pas sur le sol  
  vY(i) = vY(i-1) - g*deltaT;
  x(i) = x(i-1) + vX*deltaT;
  y(i) = y(i-1) + vY(i)*deltaT;
  i = i + 1;                      // on passe à l'indice de tableau suivant
end

// Affichage du mouvement dans le repère choisi
plot2d(x,y,rect=[0,0,20,y0],style = 5);
xtitle('Chute d''un corps','X','Y');